#include "common.slang"

struct VertexShaderInput {
    // Per Vertex
    uint vertex_id : SV_VertexID;
    float3 pos;

    // Per Instance
    float4 pos_size;
    float4 uv0uv1;
    float4 uv2uv3;
};

struct VertexShaderOutput {
    float4 pos : SV_POSITION;
    float2 uv;
};

struct PixelShaderOutput {
    float4 color : SV_TARGET;
};

[shader("vertex")]
VertexShaderOutput main_vertex(VertexShaderInput input) {
    VertexShaderOutput output;

    output.pos = mul(view_projection_matrix, float4(input.pos_size.xy + input.pos.xy, 0, 1));
    
    switch(input.vertex_id) {
        case 0: output.uv = input.uv0uv1.xy; break;
        case 1: output.uv = input.uv0uv1.zw; break;
        case 2: output.uv = input.uv2uv3.xy; break;
        case 3: output.uv = input.uv2uv3.zw; break;
    }

    return output;
}

[[vk::binding(0, 2)]]
Sampler2D<float4> tex1;

[[vk::binding(0, 3)]]
cbuffer fragment_constants {
    float3 tint;
}

[shader("pixel")]
PixelShaderOutput main_fragment(VertexShaderOutput input) {
    PixelShaderOutput output;

    output.color = tex1.PixelArtSample(input.uv);
    output.color.rgb *= tint.rgb;
    
    return output;
}